En el entorno DOS de la era 8086, la pantalla de texto típicamente se basaba en el BIOS y el generador de caracteres integrado del adaptador gráfico en lugar de cualquier sistema sofisticado de rendimiento de fuentes. Las fuentes estaban firmemente unidas a modos de texto específicos implementados por adaptadores como CGA, EGA o VGA. Uno de los modos más comunes era el modo de texto 03h, que presentaba una red de texto de 80 × 25. En uno de nuestros anteriores buceos profundos, exploramos el infame y cómo integrar los temporizadores de hardware para producir beeps simples con el Esta vez, cambiaremos la apariencia de un caracter ASCII (en este caso 'A' ) redefiniendo sus datos de píxeles. VGA-Modo 13h PC-espectadores ASCII y el conjunto de caracteres DOS ASCII (American Standard Code for Information Interchange) es originalmente un código de 7 bits que define caracteres (letras, dígitos, puntuación) en el rango 0-127 .En DOS, el conjunto ASCII extendido estándar (a menudo llamado Code Page 437) agregó otros 128 caracteres (128-255), incluyendo caracteres de dibujo de caja, símbolos y otros glifos utilizados con frecuencia en el mundo de DOS. Modo de texto 03h (80×25) Uno de los modos de pantalla típicos utilizados en 8086 DOS para la salida de texto es el Modo 03h. En el Modo 03h, la pantalla se divide en 80 columnas y 25 líneas de caracteres de texto. que posee un personaje más atributos (como los colores del antepasado y del fondo, los flashes, etc.). cell 
 
 
 Con el primer CGA (Color Graphics Adapter), cada celda de texto era típicamente una matriz de píxeles 8×8 (aunque algunos adaptadores podrían utilizar efectivamente 8×14 o 9×14 para EGA, y 9×16 para VGA). Para el VGA estándar en el modo de texto 80×25, cada celda de caracteres suele ser de 9 píxeles de ancho y 16 píxeles de alto (aunque el glifo real en sí solo puede ocupar 8 píxeles de ancho, con la 9a columna utilizada para el espaciamiento u otras características). Si se considera el modo de texto VGA típico de células de caracteres 9×16 en 80×25, la resolución total de la pantalla en términos de píxeles en bruto es 720×400 (80 columnas × 9 píxeles ancho, 25 líneas × 16 píxeles alto). En el modo 03h, cada caracter se almacena en RAM de vídeo (en ES:DI B800h:0000h) con un Byte para el índice de caracteres (00h - FFh) y otro byte para definir el color del antepasado y el color del fondo (0-F para el fondo y 0-F para el antepasado). ¿Cómo es? Puede que desee mostrar sus propios símbolos, o ser creativo con gráficos ASCII. En DOS y otros entornos de bajo nivel, usted tiene una increíble capacidad de poke la memoria BIOS o VGA directamente para definir lo que los píxeles de cada personaje parecen. Usaremos la interrupción del BIOS 10h con AL = 11h para cargar nuestra fuente personalizada. Paso a paso Primero, clonemos nuestro entorno de inicio de nuevo para que puedas seguirlo: git clone git@github.com:MilesTails01/i8086_boilercode.git
 Después de descargar, debe desempacar DOSBOX.zip y TOOLS.zip cd \bin
tar -xf TOOLS.zip
tar -xf DOSBOX.zip

build.bat   // Compile, Link and Start the source
debug.bat   // Starts AFDEBUG and loads the compiled exe
start.bat   // Start the program without rebuilding it
 Elimine todo lo que no sea necesario. Mantenga el código simple y comience con el mínimo ;   #################################
;   #           ASCII.ASM           #
;   #################################

;   #################################
;   #           STACK               #
;   #################################
STACK SEGMENT PARA STACK
    db 256 dup(0)
STACK ENDS

;   #################################
;   #           DATA                #
;   #################################
DATA SEGMENT PARA 'DATA'
DATA ENDS

;   #################################
;   #           CODE                #
;   #################################
CODE SEGMENT PARA 'CODE'

    ASSUME cs:CODE, ds:DATA, ss:STACK
    mov ax, DATA
    mov ds, ax
    mov ax, STACK
    mov ss, ax
    mov sp, 256

CODE ENDS
 Paso 1 Definamos nuestros datos de píxeles de caracteres primero. se convertirá en el color de fondo y Tenga en cuenta en el modo normal 80x25 la dimensión para un personaje son 9x16. Definiremos 14 líneas cada línea que contiene 8bit causa (tened en cuenta para hacer el 9 bit 0 causa db está limitado a 1 byte). Este personaje será bloque de barras si te preguntas qué va a parecer más adelante. 0 1 CHAR_DATA   db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
            db  010101010b
 Paso 2 Definamos una función de impresión para llenar toda la pantalla con el caracter A PRINT PROC NEAR
    mov ax, 0B800h      ; VGA text mode memory segment
    mov es, ax
    mov di, 0           ; Start at the top-left of the screen
    mov cx, 2000        ; 80x25 screen = 2000 characters
    mov al, 'A'         ; ASCII code for 'A'
    mov ah, 19h         ; Attribute byte (blue on white)
    rep stosw           ; Fill screen with 'A'
    ret
PRINT ENDP
 Paso 3 Ahora la parte importante: usaremos interrupt 10h (Bios Interrupt) con AH fijado a 11h. He escrito la definición del parámetro para AX, BX, CX, DX y BP en los comentarios. REPLACE_ASCII PROC NEAR
    ;   mov ax, 03h         ; Set video mode to text mode (80x25, color)
    ;   int 10h             ; 9x16 font size
    ;
    ;   mov ax, 1112h       ; Force 8x8 font size for character cells
    ;   xor bl, bl          ; RAM block
    ;   int 10h

    ; Change text mode character (int 10h)
    ; AH    = 11h   
    ; BH    = Number of bytes per character
    ; CX    = Number of characters to change
    ; DX    = Starting character to change
    ; ES:BP = Offset of character data

    push ds
    pop es              ; make sure es = ds
    lea bp, CHAR_DATA   ; Pointer to custom font data
    mov ax, 1100h       ; Load user-defined font
    mov bh, 0Eh         ; Number of bytes per character
    xor bl,bl           ; RAM block
    mov cx, 01h         ; Number of characters to replace = 1 for now
    mov dx, 41h         ; Starting character to change (41h = 'A' in ASCII)
    int 10h             ; Call BIOS to load the font

    ret
REPLACE_ASCII ENDP
 Paso 4 Opcional: si lo desea puede imprimir la tabla ASCII actual en el medio de la pantalla ;) ASCIIPRINT PROC NEAR
    mov ax, 0B800h      ; VGA text mode memory segment
    mov es, ax
    xor di, di          ; Reset offset

    mov cx, 5           ; Total number of characters (0-255)
    mov ah, 4Fh         ; Attribute byte (red on white)
    mov dl, 10          ; Padding on the left (adjust as needed)
    mov dh, 60          ; Total width of the centered line (adjust as needed)
    mov di, 1620        ; Row (10 x 80 + padding) * 2, starting with left padding


PrintLoop:
    stosw               ; Store the character (AL) and attribute (AH)
    inc al              ; Move to the next ASCII character
    dec dh              ; Decrement width counter
    jnz PrintLoop       ; Continue until row width is filled
    add di, 40          ; Move to the next row with padding ((80 - 60) * 2)
    mov dh, 60          ; Reset row width
    loop PrintLoop      ; Repeat for all 256 characters

    ret
ASCIIPRINT ENDP
 Resultado Cada personaje de A fue reemplazado por el nuevo bloque de franjas.Este Glyph será muy útil en un artículo posterior. Código completo ;   #################################
;   #           ASCII.ASM           #
;   #################################

;   #################################
;   #           STACK               #
;   #################################
STACK SEGMENT PARA STACK
    db 256 dup(0)
STACK ENDS

;   #################################
;   #           DATA                #
;   #################################
DATA SEGMENT PARA 'DATA'
    CHAR_DATA   db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
                db  010101010b
DATA ENDS

;   #################################
;   #           CODE                #
;   #################################
CODE SEGMENT PARA 'CODE'

    ASSUME cs:CODE, ds:DATA, ss:STACK
    mov ax, DATA
    mov ds, ax
    mov ax, STACK
    mov ss, ax
    mov sp, 256

;   #################################
;   #           MAIN                #
;   #################################

    call REPLACE_ASCII
    call PRINT
    call ASCIIPRINT

    ret

;   =============================
;   |   FUNCTIONS               |
;   =============================

PUBLIC REPLACE_ASCII

REPLACE_ASCII PROC NEAR
    ;   mov ax, 03h         ; Set video mode to text mode (80x25, color)
    ;   int 10h             ; 9x16 font size
    ;
    ;   mov ax, 1112h       ; Force 8x8 font size for character cells
    ;   xor bl, bl          ; RAM block
    ;   int 10h

    ; Change text mode character (int 10h)
    ; AH    = 11h   
    ; BH    = Number of bytes per character
    ; CX    = Number of characters to change
    ; DX    = Starting character to change
    ; ES:BP = Offset of character data

    push ds
    pop es              ; make sure es = ds
    lea bp, CHAR_DATA   ; Pointer to custom font data
    mov ax, 1100h       ; Load user-defined font
    mov bh, 0Eh         ; Number of bytes per character
    xor bl,bl           ; RAM block
    mov cx, 01h         ; Number of characters to replace = 1 for now
    mov dx, 41h         ; Starting character to change (41h = 'A' in ASCII)
    int 10h             ; Call BIOS to load the font

    ret
REPLACE_ASCII ENDP

PRINT PROC NEAR
    mov ax, 0B800h      ; VGA text mode memory segment
    mov es, ax
    mov di, 0           ; Start at the top-left of the screen
    mov cx, 2000        ; 80x25 screen = 2000 characters
    mov al, 'A'         ; ASCII code for 'A'
    mov ah, 19h         ; Attribute byte (blue on white)
    rep stosw           ; Fill screen with 'A'
    ret
PRINT ENDP

ASCIIPRINT PROC NEAR
    mov ax, 0B800h      ; VGA text mode memory segment
    mov es, ax
    xor di, di          ; Reset offset

    mov cx, 5           ; Total number of characters (0-255)
    mov ah, 4Fh         ; Attribute byte (red on white)
    mov dl, 10          ; Padding on the left (adjust as needed)
    mov dh, 60          ; Total width of the centered line (adjust as needed)
    mov di, 1620        ; Row (10 x 80 + padding) * 2, starting with left padding


PrintLoop:
    stosw               ; Store the character (AL) and attribute (AH)
    inc al              ; Move to the next ASCII character
    dec dh              ; Decrement width counter
    jnz PrintLoop       ; Continue until row width is filled
    add di, 40          ; Move to the next row with padding ((80 - 60) * 2)
    mov dh, 60          ; Reset row width
    loop PrintLoop      ; Repeat for all 256 characters

    ret
ASCIIPRINT ENDP

CODE ENDS
END


Walkthroughs, tutorials, guides, and tips. This story will teach you how to do something new or how to do something better.

Visit My Website

Read My Stories

Este audio es producido en el idioma original de la historia!

Redefinición de “A” en el modo VGA 03h

About Author

COMENTARIOS

ETIQUETAS

ESTE ARTÍCULO FUE PRESENTADO EN

Related Stories

Las capas invisibles: por qué las entrevistas con los usuarios son un activo irremplazable

Crecimiento de las criptomonedas: creación de perfiles de usuarios eficaces

Una guía del arquitecto para crear una arquitectura de referencia para un lago de datos de IA/ML

Cómo mejorar su flujo de trabajo 10 veces: 17 aplicaciones esenciales

Las capas invisibles: por qué las entrevistas con los usuarios son un activo irremplazable

Crecimiento de las criptomonedas: creación de perfiles de usuarios eficaces

Una guía del arquitecto para crear una arquitectura de referencia para un lago de datos de IA/ML

Cómo mejorar su flujo de trabajo 10 veces: 17 aplicaciones esenciales

Light-Mode

Classic

Newspaper

Minty

Dark-Mode

Neon Noir

Minty

HN StartUps